Roof penetrates floor in caving simulation

FLAC3D
1

Hey there! congrats on this nice forum.

I’ve currently built a very basic model to test some scripts in it and I’m facing the first big problem.

I’m simulating a longwall panel which is exploited in 5 mining stages, however when I do the third cut, the ‘roof’ of the panel deforms so much to the point in which it touches the floor and beyond that, which is clearly physically impossible.

The thickness of the coal seam is 5 meters, and the displacements are way bigger than that and you can see that the model obviously doesn’t converge due to this. It eventually leads to illegal geometry as well.

I was told that the way of dealing with this is by adding a simple interface in the roof, and set sound properties, and that would suffice, however penetration keeps on occurring after doing so.

panel roof outside
panel roof outside1069×561 96.9 KB

What’s the course of action for such a problem? of course, this is large-strain mode.

Thanks a lot in advance.

panel roof inside
panel roof inside1040×599 50.8 KB

2

Well, I fixed this issue.

If anyone’s interested, interfaces do work for this situation, just make sure you aren’t deleting them when excavating the panel.

Cheers,

image
image1197×719 121 KB

1 Like
3

Hello there! I just started using FLAC3D for my research in surface subsidence caused by longwall mining. I also met a same problem where my displacement go higher than the longwall panel height (which is impossible). Is it possible to share your dat file so I can learn from it? I really appreciate it if you want to share it with us.Thank you!

4

Sorry the late response but I’d forgotten my login lol

This is for geometry

model new
zone import 'test_caving_GVol_Binary.f3grid'

zone face skin

zone group 'panel_1' slot 'panels' range group 'ZG_002'
zone group 'panel_2' slot 'panels' range group 'ZG_004' 
zone group 'panel_3' slot 'panels' range group 'ZG_003' 
zone group 'panel_4' slot 'panels' range group 'ZG_005' 
zone group 'panel_5' slot 'panels' range group 'ZG_006' 

zone group 'box' slot 'geology' range group 'ZG_001'

zone group "pnl" range group 'panel_1' or 'panel_2' or 'panel_3' or 'panel_4' or 'panel_5'

zone group 'roof' range plane normal 0,0,1 above ori 0 0 152.5

zone face group 'int' internal range group "pnl" group "roof"
zone interface create by-face separate range group 'int'

zone interface node prop stiffness-norm 1e10 stiffness-shear 1e10 fric 35 coh 1e6 tension 1e5

model save 'Geometry.f3sav'

This is the next file

model restore 'Geometry.f3sav'
model large-strain on


zone cmodel assign mohr-coulomb range group 'panel_1' or 'panel_2' or 'panel_3' or 'panel_4' or 'panel_5'...
or 'box'

zone property cohesion 1.5e6 friction 35 tens 0.1e3 young 25e9 poisson 0.25 density 2600 range group 'box'
zone property cohesion 0.5e6 friction 30 tens 0.05e3 young 5e9 poisson 0.3 density 2400 range group 'panel_1' or 'panel_2' or 'panel_3'...
or 'panel_4' or 'panel_5'

model grav 0 0 -9.81
zone face apply velocity-x 0 range group 'East' or 'West' 
zone face apply velocity-y 0 range group 'North' or 'South' 
zone face apply velocity-z 0 range group 'Bottom' 



; Apply vertical stress on the top boundary
zone face apply stress-zz -3e6 range group 'Top'
zone face apply stress-xx -1.5e6 range group 'East'
zone face apply stress-yy -6e6 range group 'North'

; Initialize in-situ horizontal stresses
;zone initialize stress xx -1.5e6 yy -6e6 zz 0

;zone interface node ini-stress

model solve elas ratio 1e-5
model save 'insitu.f3sav'

After this one, excavation stages which all look the same

model restore 'insitu.f3sav'
zone initialize state 0
zone gridpoint initialize displacement (0,0,0)

zone relax excavate range group 'panel_1'
model solve ratio 1e-5
model save 'exc1.f3sav'

Hope this helps,

Cheers,

FELIPE