I have created a rock model with two joint sets- one horizontal and the other at angle 30 deg to the horizontal. The model is 50x50m and has joint sets at 1 m spacing. The excavation of tunnel and loading area have been created using circular arc. The excavations have not been done yet. When I am applying vertical stresses and running the model, I am not able to achieve equilibrium. The criteria for achieving equilibrium is to achieve a solve ratio of 1e-5. But it is not achieved. Please provide suggestions. The bottom and side boundaries are roller boundaries. Thank you.
There is not much information to go on. If that is all of your input that you can share publicly, then I would suggest contacting the Itasca support.
Otherwise check the usual suspects: Are your boundary conditions not applied where you want them? Are there large displacements/velocities somewhere? Are some properties ill-defined, etc…
I am sharing the script here
model new
;create tunnel model in this step
block tolerance corner-round-length 0.00001
;define original boundary of the problem
block create polygon 0.0 0.0 50.0 0.0 50.0 -50.0 0.0 -50.0
;generate joint patterns over the region
block cut joint-set angle 0 spacing 1.0 origin 0.0 0.0
block cut joint-set angle 30 spacing 1.0 origin 0.0 0.0
;create tunnel
block cut arc 25.0 -29.0 29.0 -29.0 360 36 join
;create hemisphere for loading later
block cut arc 25.0 0.0 20.0 0.0 180 36 join
;create zones
block zone gen edge 0.50 range pos-x 0.0 50.0 pos-y 0 -50.0
model save 'step1.sav'
;
fish define constants
j_kn1 = 80.0e9
j_ks1 = 40.0e9
c1 = 16.0e6
f1 = 35
end
@constants
;
;assign rock properties
block zone group 'rock' range pos-x 0.0 50.0 pos-y 0.0 -50.0
block zone cmodel assign elastic density 2620.00 bulk 68e9 shear 37e9 range group 'rock'
block contact group 'contact1' range pos-x 0.0 50.0 pos-y 0.0 -50.0
block contact cmodel assign area st-n @j_kn1 st-s @j_ks1 coh @c1 fric @f1 range group 'contact1'
block contact cmodel default area st-n @j_kn1 st-s @j_ks1 coh @c1 fric @f1 range group 'contact1'
block contact tolerance overlap 0.0001 range group 'contact1'
block edge apply stress 0.0 0.0 0.0 gradient-y 2620.0 0.0 2620.0
block insitu stress 0.0 0.0 0.0 gradient-y 2620.0 0.0 2620.0
;roller boundaries
block gridpoint apply vel-y 0.0 range pos-x -0.10 50.10 pos-y -49.50 -50.50 ;bottom bound
block gridpoint apply vel-x 0.0 range pos-x -0.10 0.10 pos-y -0.10 -50.10 ;left y bound
block gridpoint apply vel-x 0.0 range pos-x 49.50 50.50 pos-y -0.10 -50.10 ;right y bound
model gravity 0 -10
;track x and y displacement over time
block gridpoint history disp-x 29.0 -29.0; springline right
block gridpoint history disp-x 25.0 -25.0; crown
block gridpoint history disp-x 21.0 -29.0; springline left
block gridpoint history disp-x 25.0 -33.0; bottom/base
block gridpoint history disp-y 29.0 -29.0; springline right
block gridpoint history disp-y 25.0 -25.0; crown
block gridpoint history disp-y 21.0 -29.0; springline left
block gridpoint history disp-y 25.0 -33.0; bottom/base
block mechanical history unbalanced-maximum
block solve ratio 1e-5
model save 'step2.sav'
;
;perform excavations
block delete range circle center 25.0 -29.0 radius 4.00
block delete range circle center 25.0 0.0 radius 5.00
block solve ratio 1e-5
model save 'step3.sav'
;
The model runs now; however the displacements I am getting are quite large. Please check.
Check contact/ joint properties.
I checked the joint properties. If I increase it by 3 orders i.e. multiply it by 10^12, the problem does not converge. When multiplying joint stiffnesses with 10^11 or 10^10, the problem converges however there is not much difference in displacments compared to what I got with stiffnesses at 10^9 level. If I lower it below 10^9, then overlap issues happen.
I think the your initial stresses are wrong. If they were right, the model should equilibrate very quickly without much stress change, but in your case, the stresses increase strongly, which leads to long solve times and comparatively large displacements.
When I change the gradient-y to 26200.0 the model is immediately recognized as solved and excavation can start.
2 Likes
Yes, you have rightly pointed out. It get immediately solved. Thank you very much. 
When I move on to excavation stage, it takes around 20000 steps or more to reach to equilibrium (solve ratio 1e-5). Is this okay?
1e-5 is ok. but it should be taken as per your model requirements as it will increase or decrease the nos. of cycles/ steps.
1 Like